Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Sumar solo las filas filtradas, también con una condición adicional

Usted filtra una lista de ventas por una sola categoría, pero el total que aparece debajo sigue mostrando el importe de todas las filas. Es correcto: SUMA también cuenta las filas que el filtro oculta. Si solo desea sumar lo que ve, utilice SUBTOTALES. Y si dentro de las filas filtradas necesita una condición adicional, u omitir valores de error, dispone de otras dos fórmulas útiles. Euro-Office muestra los nombres de función en español (SUMA, SUBTOTALES, SUMAR.SI.CONJUNTO, AGREGAR), con punto y coma entre los argumentos y coma como separador decimal.

Como ejemplo tomamos la lista de ventas de Bloemisterij Het Zonnetje: en A la fecha, en B el producto, en C la categoría y en D el importe, de la fila 2 a la 300. Hay un filtro en la fila de encabezado (consulte Ordenar y filtrar).

¿Dónde colocar las fórmulas?

No debajo de la lista: una fórmula situada justo debajo de la lista puede quedar oculta al filtrar y desplazarse al ordenar. Pero tampoco simplemente al lado de la lista: un filtro oculta filas enteras, de modo que una fórmula en F3 desaparece también si la fila 3 queda filtrada. Colóquelas por tanto en la fila de encabezado (fila 1, junto a los títulos) o en una hoja de cálculo aparte. En el ejemplo están en la fila 1, a partir de la columna F.

La suma de las filas visibles

=SUBTOTALES(109;D2:D300)

El primer número elige el cálculo. 9 es la suma, 109 también, con una diferencia: 109 omite además las filas que haya ocultado manualmente (clic con el botón derecho, Ocultar). 9 solo omite las filas que oculta el filtro. Utilice por tanto 109 si desea sumar lo que ve.

CálculoFiltradoTambién ocultas manualmente
Suma9109
Número de celdas con contenido3103
Punto medio1101
Máximo4104

El número de filas visibles se cuenta con =SUBTOTALES(103;B2:B300).

SUBTOTALES suma solo las filas visibles
Filtrado por Boeketten: SUBTOTALES(109;...) en G1 suma solo los importes visibles de la columna Bedrag (1); abajo se indica que se han filtrado 40 de 83 registros. En K1 la fórmula con DESREF (#¡NUM!), en M1 la fórmula SUMAR.SI.CONJUNTO con la columna auxiliar Puede ver

Visible y con una condición adicional

Ha filtrado por la categoría Boeketten y dentro de ella desea sumar solo los arreglos fúnebres. SUMAR.SI.CONJUNTO no tiene en cuenta el filtro y SUBTOTALES no admite condiciones. En internet encontrará para ello una fórmula con SUMAPRODUCTO, SUBTOTALES y DESREF. En Euro-Office esa fórmula devuelve el valor de error #¡NUM!. Con una columna auxiliar sí funciona, y de forma más sencilla:

  1. Añada junto a la lista una columna Puede ver, aquí la columna E. Seleccione E2:E300, escriba =SUBTOTALES(103;D2) y pulse Control+Intro. Cada fila obtiene un 1 mientras esté visible y un 0 si el filtro la oculta.
  2. Sume con SUMAR.SI.CONJUNTO e incluya la columna auxiliar como condición adicional: =SUMAR.SI.CONJUNTO(D2:D300;B2:B300;"Rouwstuk";E2:E300;1).

Si cambia el filtro, la columna auxiliar y la suma se recalculan al instante.

Omitir valores de error

Si en alguna parte de la columna aparece un #N/A o un #¡DIV/0!, SUMA y SUBTOTALES también devuelven un valor de error. AGREGAR puede omitir los errores:

=AGREGAR(9;7;D2:D300)

El 9 vuelve a ser la suma; el 7 significa: omitir las filas ocultas y los valores de error.

Errores frecuentes

  • Las columnas ocultas sí se tienen en cuenta: SUBTOTALES solo considera las filas ocultas.

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…