Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Mostrar el top 5 por categoría

Los productos más vendidos por departamento, los mayores clientes por región, los días con más actividad por mes: no busca el top 5 de toda la lista, sino el top 5 dentro de una categoría. K.ESIMO.MAYOR trabaja sobre toda la columna y, si hay importes iguales, devuelve dos veces el mismo producto. En Euro-Office puede resolverlo con una sola fórmula.

Como ejemplo tomamos la facturación anual por producto de Bloemisterij Het Zonnetje: en la columna A el producto, en B la categoría (Rozen, Tulpen, Planten) y en C la facturación, de la fila 2 a la 18. En F1 está la categoría que desea ver: Rozen.

El top 5 en una sola fórmula

Escriba en H2:

=TOMAR(ORDENAR(FILTRAR(A2:C18;B2:B18=F1);3;-1);5)

Léala de dentro hacia fuera:

  1. FILTRAR(A2:C18;B2:B18=F1) conserva solo las filas de la categoría de F1, con las tres columnas.
  2. ORDENAR(...;3;-1) ordena esas filas por la tercera columna (la facturación), de mayor a menor (-1).
  3. TOMAR(...;5) conserva las 5 primeras filas.

Pulse Intro: los cinco productos, con su categoría y su facturación, aparecen en H2 a J6. Si escribe Planten en F1, la lista cambia al instante.

El top 5 de la categoría Rozen
La categoría está en F1 (1). ORDENAR ordena por la columna Omzet (2). En F2:G6, los cinco importes más altos por categoría con K.ESIMO.MAYOR y FILTRAR; en H2:J6, el top 5 completo con TOMAR, ORDENAR y FILTRAR

Los importes iguales no son un problema: en el ejemplo, Grand Prix y Ecuadoriaanse roos tienen ambos una facturación de 3400, y los dos aparecen en la lista. Con dos veces K.ESIMO.MAYOR combinado con INDICE y COINCIDIR aparecería dos veces Grand Prix.

Solo los importes, con las categorías una al lado de otra

Si solo desea los cinco importes más altos, por ejemplo para varias categorías una al lado de otra, utilice K.ESIMO.MAYOR sobre una lista filtrada. Ponga las categorías en F1, G1 y siguientes, seleccione F2:G6 y escriba:

=SI.ERROR(K.ESIMO.MAYOR(FILTRAR($C$2:$C$18;$B$2:$B$18=F$1);FILAS($1:1));"")

y pulse Control+Intro. FILTRAR conserva solo los importes de la categoría de la fila 1. FILAS($1:1) vale 1 en la primera fila y pasa a 2, 3, 4 y 5 en las filas de debajo: el mayor, el segundo mayor, y así sucesivamente. SI.ERROR deja la celda vacía si una categoría tiene menos de cinco productos; Tulpen solo tiene cuatro.

Atención: en sitios web sobre Excel suele aparecer =K.ESIMO.MAYOR(SI($B$2:$B$18=F$1;$C$2:$C$18);FILAS($1:1)). En Euro-Office, si la confirma con un simple Intro, da un resultado incorrecto: SI no examina entonces toda la columna, de modo que obtiene los importes más altos de todas las categorías o #¡NUM!. Si la confirma con Control+Mayús+Intro, la fórmula recibe llaves {…} y el resultado sí es correcto. Usar FILTRAR como se indica arriba es más sencillo.

Solo el importe más alto

Para un único número es más sencillo: =MAX.SI.CONJUNTO(C2:C18;B2:B18;F1) devuelve la facturación más alta dentro de la categoría, en este caso 6150.

Errores frecuentes

  • Menos de 5 productos en una categoría: sin SI.ERROR, K.ESIMO.MAYOR devuelve #¡NUM! en las filas que no existen. TOMAR no tiene este problema y simplemente muestra menos filas.
  • La fórmula con TOMAR se queda vacía: hay algo en las 5 filas y 3 columnas donde debe ir el resultado. Consulte Listas que se actualizan solas con FILTRAR, UNIQUE y ORDENAR.
  • Un compañero con Excel 2019 o anterior verá #¿NOMBRE? con TOMAR, ORDENAR y FILTRAR.

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…