Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Comparar dos listas: ¿quién está en una y no en la otra?

La lista de socios frente a los pagos, los clientes del año pasado frente a los de este año, el inventario frente al pedido: usted quiere saber quién está en una lista y no en la otra. Encontrar y eliminar clientes duplicados busca duplicados dentro de una sola lista; aquí se comparan dos listas entre sí.

Como ejemplo tomamos la panadería Bakkerij De Korenaar con dos hojas de cálculo: Klanten2025 con las direcciones de correo electrónico del año pasado en A2:A8, y Klanten2026 con las de este año en A2:A7.

Método 1: una columna auxiliar con baja o sigue

En la hoja Klanten2025, escriba en B2:

=SI(CONTAR.SI(Klanten2026!$A$2:$A$7;A2)=0;"baja";"sigue")

Arrastre la fórmula hasta el último cliente. CONTAR.SI cuenta cuántas veces aparece la dirección en la lista de 2026. Si el resultado es 0, el cliente se ha dado de baja. Después puede filtrar u ordenar por la columna B (consulte Ordenar y filtrar).

Los signos de dólar son importantes: sin ellos, el rango de la otra lista se desplaza al arrastrar la fórmula y las primeras direcciones dejan de incluirse por arriba.

Método 2: una lista solo con las diferencias

En una hoja aparte, FILTRAR crea de una sola vez una lista de todos los clientes que se han ido:

=FILTRAR(Klanten2025!A2:A8;CONTAR.SI(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"ninguna baja")

Aquí CONTAR.SI recibe una lista completa como segundo argumento y cuenta a la vez para cada dirección de 2025. FILTRAR conserva las direcciones para las que el resultado es 0. Los clientes nuevos se obtienen invirtiendo las listas:

=FILTRAR(Klanten2026!A2:A7;CONTAR.SI(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"ningún cliente nuevo")

Clientes que se han ido y clientes nuevos uno al lado del otro
Clientes que se han ido (1) y clientes nuevos (2), cada uno con una sola fórmula FILTRAR

Para obtener quién aparece solo en una de las dos listas, sea nuevo o se haya ido, utilice:

=UNIQUE(APILARV(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

APILARV coloca las dos listas una debajo de la otra. UNIQUE con un 1 como tercer argumento conserva solo los valores que aparecen exactamente una vez. Si una dirección ya está duplicada dentro de una misma lista, elimine primero los duplicados de esa lista: =UNIQUE(APILARV(UNIQUE(Klanten2025!A2:A8);UNIQUE(Klanten2026!A2:A7));;1).

Método 3: colores en lugar de listas

  1. En la hoja Klanten2025, seleccione las direcciones, A2:A8.
  2. En la pestaña Inicio, elija Formato condicional, Nueva regla, tipo Fórmula.
  3. Escriba =CONTAR.SI(Klanten2026!$A$2:$A$7;$A2)=0, elija un color de relleno y haga clic en OK.

Una referencia a otra hoja en una regla de formato funciona sin problemas en Euro-Office; en versiones antiguas de Excel había que hacerlo mediante un nombre definido.

Clientes que se han ido resaltados en color
Las direcciones que ya no aparecen en 2026 se colorean de naranja; la columna B indica baja o sigue

Errores frecuentes

  • Espacios: "info@dekorenaar.nl " con un espacio al final es, para la hoja de cálculo, otra dirección distinta. Elimine primero los espacios con ESPACIOS en una columna auxiliar.
  • Las celdas vacías de un rango también cuentan como valor. Por eso, incluya solo las filas con datos o excluya las celdas vacías con <>"".
  • Números frente a texto: si compara números de cliente y el número está en una lista como texto (alineado a la izquierda en la celda) y en la otra como número, no coincidirán. Consulte BUSCARV devuelve #N/A: así se soluciona.
  • No escriba VERDADERO sin paréntesis como tercer argumento de UNIQUE; Euro-Office solo reconoce TRUE, VERDADERO() o 1 (consulte Copiar fórmulas de Excel: nombres de función en español y el punto y coma).

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…