Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Extraer la calle, el número y el complemento de una sola columna de direcciones

Las direcciones procedentes de una tienda online, de un registro de socios o de un antiguo fichero de clientes suelen estar en una sola columna: "Dorpsstraat 12-2". Para etiquetas de envío, un mailing o una importación en el sistema de una empresa de transporte, la calle, el número y el complemento deben ir por separado. Con Texto en columnas esto no funciona bien, porque los nombres de las calles también contienen espacios. Cómo separar el nombre y los apellidos se explica en Separar nombre y apellido de una sola columna; las direcciones son más complicadas. Para ello, Euro-Office dispone de las funciones REGEXEXTRACCION y REGEXREEMPLAZAR, que trabajan con un patrón de búsqueda.

Como ejemplo tomamos la lista de clientes de Bloemisterij Het Zonnetje, con lo siguiente en la columna A:

  • Koningin Julianalaan 15 a
  • Dorpsstraat 12-2
  • Laan 1940-1945 8B
  • Kerkplein 7
  • Hoofdstraat 120 bis

Paso 1: el número con su complemento

Escriba en B2:

=REGEXEXTRACCION(A2;"\d+\S*( ?[A-Za-z]{1,3})?$")

El patrón entre comillas significa: una o más cifras (\d+), después, opcionalmente, caracteres sin espacio (\S*, como -2 o B), después, opcionalmente, un espacio con 1 a 3 letras (como " a" o " bis"), y todo ello justo al final del texto ($). Resultado: 15 a, 12-2, 8B, 7 y 120 bis. Los años de "Laan 1940-1945" quedan fuera, porque solo cuenta la última parte de la dirección.

Paso 2: la calle

Escriba en C2:

=ESPACIOS(REGEXREEMPLAZAR(A2;"\d+\S*( ?[A-Za-z]{1,3})?$";""))

REGEXREEMPLAZAR sustituye esa misma parte por nada, y ESPACIOS elimina el espacio que queda al final. Obtendrá Koningin Julianalaan, Dorpsstraat, Laan 1940-1945, etc.

Paso 3: el número y el complemento por separado

Si también necesita separar el número y el complemento, siga trabajando con el resultado del paso 1 en B2:

  • Solo el número, en D2: =REGEXEXTRACCION(B2;"^\d+") (las cifras del principio): 15, 12, 8, 7, 120.
  • El complemento, en E2: =ESPACIOS(REGEXREEMPLAZAR(B2;"^\d+[- ]?";"")): a, 2, B, nada, bis.

Después, arrastre las fórmulas hasta la última fila. O trabaje por columnas: seleccione, por ejemplo, B2:B6, escriba la fórmula y pulse Ctrl+Intro; así se introduce de una vez en todas las celdas seleccionadas.

Direcciones separadas en calle, número y complemento
Número con complemento (1), calle (2), número (3) y complemento (4), cada uno con una sola fórmula

Una dirección con comas

Si toda la dirección está en una sola celda, como "Dorpsstraat 12, 1234 AB Utrecht", =DIVIDIRTEXTO(A9;", ") la divide por la coma: "Dorpsstraat 12" queda en la propia celda y "1234 AB Utrecht" en la celda contigua. Después, separe el código postal y la localidad con TEXTOANTES y TEXTODESPUES, que toman el texto anterior o posterior a la enésima aparición de un delimitador. Si "1234 AB Utrecht" está en C9:

  • Código postal: =TEXTOANTES(C9;" ";2) devuelve 1234 AB (todo lo que hay antes del segundo espacio).
  • Localidad: =TEXTODESPUES(C9;" ";2) devuelve Utrecht.

¿Listo? Conviértalo en valores fijos

Las columnas separadas son fórmulas que hacen referencia a la columna A. Si desea eliminar la columna A o enviar el archivo a alguien con una versión antigua de Excel, convierta antes los resultados en texto normal: seleccione las columnas, cópielas con Ctrl+C y péguelas en el mismo lugar con Ctrl+V. Debajo de las celdas pegadas aparece un pequeño botón (Control). Haga clic en él y, en Valor, elija Pegar solo valor.

Las opciones de pegado después de pegar
El botón (Control) debajo de las celdas pegadas, con la opción Pegar solo valor en Valor

Errores frecuentes

  • Las excepciones seguirán existiendo: "Postbus 12", "Hoofdstraat 3 hs", "tegenover 14". Aplique un filtro a las columnas y revise los resultados vacíos o extraños antes de utilizar la lista.
  • Mayúsculas: el patrón [A-Za-z] incluye minúsculas y mayúsculas. Si utiliza solo [a-z], 8B quedará fuera.
  • #N/D en REGEXEXTRACCION significa que el patrón no aparece, por ejemplo, en una dirección sin número.
  • Otras hojas de cálculo: Excel solo incluye estas funciones REGEX en las versiones recientes de Microsoft 365. Un compañero con una versión anterior verá #¿NOMBRE?. En ese caso, convierta antes los resultados en valores.
  • También es posible sin REGEX, aunque de forma más limitada: =TEXTODESPUES(A2;" ";-1) devuelve todo lo que hay después del último espacio. Funciona con "Kerkplein 7" y "Dorpsstraat 12-2", pero con "15 a" solo obtendrá la a.

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…