Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Buscar según dos condiciones a la vez

BUSCARV y BUSCARX buscan según un único valor (consulte BUSCARV devuelve #N/A: así se soluciona y BUSCARX: buscar hacia la izquierda y con un mensaje propio). En la práctica, a menudo necesitará buscar según dos criterios a la vez: el precio de un ramo en talla L, la tarifa de un cliente en un año concreto, las existencias de un producto en un color determinado. Para ello hay tres buenos métodos, y todos funcionan pulsando simplemente Intro. Un cuarto método que se ve mucho en internet no funciona en Euro-Office sin más.

Como ejemplo tomamos la lista de precios de Bloemisterij Het Zonnetje. El mismo producto aparece varias veces, en distintas tallas:

ABC
1ProductoTallaPrecio
2RamoS17,50
3RamoM24,50
4RamoL34,50
5Corona fúnebreM65,00
6Corona fúnebreL89,00
7Ramo de noviaM79,50

El producto buscado está en F2 (Ramo) y la talla en G2 (L). Buscamos 34,50.

Método 1: BUSCARX con valores combinados

=BUSCARX(F2&"|"&G2;A2:A7&"|"&B2:B7;C2:C7;"no encontrado")

El signo & une textos. F2&"|"&G2 se convierte en "Ramo|L". A2:A7&"|"&B2:B7 crea una combinación de ese tipo para cada fila de la lista ("Ramo|S", "Ramo|M", etc.), y BUSCARX busca en ellas. La barra vertical | entre ambos valores evita que dos combinaciones distintas den por casualidad el mismo texto. Si la combinación no existe, por ejemplo una corona fúnebre en talla S, obtendrá "no encontrado".

Búsqueda por producto y talla
BUSCARX en H2 (1) devuelve 34,50 (la fórmula se ve en la barra de fórmulas) para un ramo en talla L. Debajo: INDICE con multiplicación (#N/A), FILTRAR, INDICE sobre la tabla de precios, SUMAR.SI.CONJUNTO, una combinación que no existe, rangos de distinto tamaño (#¡VALOR!) y SUMAR.SI.CONJUNTO sin coincidencias (0)

Si después de escribir la fórmula mira la barra de fórmulas, verá una @ delante de A2:A7 y B2:B7. Euro-Office la añade automáticamente; el resultado es correcto.

Método 2: FILTRAR para todas las coincidencias

=FILTRAR(C2:C7;(A2:A7=F2)*(B2:B7=G2);"ninguno")

FILTRAR no devuelve solo la primera fila, sino todas las filas que cumplen ambas condiciones. Si una combinación aparece dos veces, verá los dos precios uno debajo del otro. Por eso, asegúrese de que haya espacio libre debajo de la fórmula (consulte Listas que se actualizan solas con FILTRAR, UNIQUE y ORDENAR). Para "o" en lugar de "y", utilice el signo más: (A2:A7="Ramo")+(A2:A7="Corona fúnebre").

Método 3: SUMAR.SI.CONJUNTO si la combinación es única

=SUMAR.SI.CONJUNTO(C2:C7;A2:A7;F2;B2:B7;G2)

Suena extraño, porque no quiere sumar nada. Pero si cada combinación aparece una sola vez, la suma es simplemente ese único precio. La ventaja: SUMAR.SI.CONJUNTO es sencillo, rápido y funciona en cualquier versión de Excel. El inconveniente: si la combinación no existe, obtendrá 0 (0,00 €) en lugar de un aviso. Y si la combinación aparece por error dos veces, obtendrá la suma de ambos precios.

Lo que encontrará en internet: INDICE y COINCIDIR con una multiplicación

Muchas webs sobre Excel proponen =INDICE(C2:C7;COINCIDIR(1;(A2:A7=F2)*(B2:B7=G2);0)). En Euro-Office, esa fórmula devuelve #N/A al pulsar simplemente Intro, incluso si la combinación existe. Si la confirma con Control+Mayús+Intro, la fórmula aparece entre llaves {…} y sí funciona. Es fácil olvidarlo, así que es mejor utilizar BUSCARX o FILTRAR, descritos más arriba.

Buscar por fila y columna

Si su lista de precios es una tabla con los productos uno debajo del otro y las tallas una al lado de la otra (una matriz), utilice INDICE con dos COINCIDIR. Con los productos en A11:A13, las tallas S, M y L en B10:D10 y los precios en B11:D13:

=INDICE(B11:D13;COINCIDIR(F2;A11:A13;0);COINCIDIR(G2;B10:D10;0))

El primer COINCIDIR busca la fila del producto y el segundo, la columna de la talla. INDICE toma la celda de la intersección.

¿Cuál elegir?

SituaciónMejor opción
Una única respuesta, con un aviso claro si no existeBUSCARX con valores combinados
El archivo también debe funcionar en una versión antigua de ExcelSUMAR.SI.CONJUNTO
Puede haber varias coincidenciasFILTRAR
Tabla de precios con las tallas como encabezados de columnaINDICE con dos COINCIDIR

Errores frecuentes

  • #N/A aunque la combinación sí existe: a menudo se debe a un espacio detrás de un valor ("Ramo ") o a un número guardado como texto. Consulte BUSCARV devuelve #N/A: así se soluciona.
  • Rangos de distinta longitud: =BUSCARX(F2;A2:A7;C2:C50) devuelve #¡VALOR!. Haga que todos los rangos empiecen y terminen en la misma fila.
  • Columnas completas (A:A) en estas fórmulas ralentizan un archivo grande, porque Euro-Office tiene que combinar entonces un millón de filas. Utilice un rango fijo, como A2:A500. Consulte Cómo hacer que una hoja de cálculo lenta vaya más rápido.
  • Un compañero con Excel 2019 o anterior verá #¿NOMBRE? en BUSCARX y FILTRAR.

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…