Ir directamente al contenido

Ajustes de cookies

Elija por tipo qué cookies permite. Puede cambiar su elección en cualquier momento en Ajustes de cookies, al pie de cada página. Declaración de privacidad

Necesarias

Siempre activadas

Necesarias para iniciar sesión, conservar su carrito y recordar sus preferencias. Siempre están activadas.

¿Qué cookies?
  • weboke_sessie, weboke_klant, weboke_remember: su sesión y mantener la sesión iniciada
  • weboke_basket: su carrito
  • wkBtwIncl: mostrar los precios con o sin IVA
  • wok_cookies: su elección de cookies, 12 meses

Mide qué anuncio lleva a una visita o a un pedido, para no pagar por anuncios que no sirven de nada.

¿Qué cookies?
  • Google Ads a través de Google Tag Manager (_gcl_au, _gcl_aw), hasta 90 días
  • OpenAI Ads, anuncios en ChatGPT
  • wok_aff: a través de qué socio llegó a nosotros (programa de afiliados), 60 días

4,6

País e idioma

Cada país tiene su propio sitio, con los precios y el IVA de ese país.

Ver

Sumar las ventas por mes o por periodo con SUMAR.SI.CONJUNTO

Un libro de caja, una lista de ventas o un registro de horas tiene una fecha en cada fila. Lo que usted quiere saber es el total por mes, por trimestre o entre dos fechas, y quizá también por producto. Con SUMAR.SI.CONJUNTO y dos condiciones de fecha puede crear ese resumen, y seguirá siendo correcto cuando se añadan filas. Una tabla dinámica también puede hacerlo (consulte Una tabla dinámica por mes, trimestre o semana). SUMAR.SI.CONJUNTO resulta más práctica cuando el resumen debe mantener una forma fija, por ejemplo para un informe o un presupuesto.

Como ejemplo tomamos las ventas de Bloemisterij Het Zonnetje en la hoja Verkoop: en A la fecha, en B el producto, en C la categoría y en D el importe, de la fila 2 a la 300.

Paso 1: una fila con los meses

Cree una hoja Overzicht. En lugar de escribir doce fechas, una sola fórmula las crea todas. Escriba en A2:

=FECHA.MES(FECHA(2026;1;1);SECUENCIA(12;1;0))

SECUENCIA(12;1;0) genera los números del 0 al 11, y FECHA.MES suma esa cantidad de meses al 1 de enero de 2026. Obtendrá el primer día de cada mes, de A2 a A13. Asigne a A2:A13 el formato personalizado mmmm aaaa (mediante Otros formatos, Personalizado, consulte Formatos de número personalizados: "12 uds", importes en miles, rojo si es negativo) y verá enero 2026, febrero 2026, etc.

El formato de fecha mmmm aaaa
El formato personalizado mmmm aaaa muestra el mes completo con el año

Paso 2: las ventas por mes

Escriba en B2:

=SUMAR.SI.CONJUNTO(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FIN.MES($A2;0))

SUMAR.SI.CONJUNTO suma los importes cuya fecha es mayor o igual que el primer día del mes y, además, menor o igual que el último día (FIN.MES con 0 devuelve el final del mismo mes). Arrastre la fórmula hasta B13, o seleccione B2:B13 antes de escribir y termine con Control+Intro.

Paso 3: por producto

Coloque los nombres de los productos como encabezados uno al lado del otro, por ejemplo Rozen en C1, Tulpen en D1 y Boeket en E1, y escriba en C2:

=SUMAR.SI.CONJUNTO(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FIN.MES($A2;0);Verkoop!$B$2:$B$300;C$1)

Se añade un par de condiciones: el producto debe coincidir con el encabezado. Fíjese en los signos de dólar: $A2 fija la columna de los meses, C$1 la fila de los encabezados. Así, la misma fórmula puede ocupar todo el rango. Un truco rápido: seleccione primero C2:E13, escriba la fórmula y pulse Control+Intro. Euro-Office introduce entonces la fórmula en todas las celdas seleccionadas, con las referencias ajustadas a cada celda.

Ventas por mes y por producto
Sumado por mes y por producto. En la barra de fórmulas, la fórmula de C2, que con C$1 consulta el encabezado Rozen (1)

Contar en lugar de sumar

El número de ventas por mes se cuenta con las mismas condiciones y CONTAR.SI.CONJUNTO:

=CONTAR.SI.CONJUNTO(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FIN.MES($A2;0))

Un periodo libre

Escriba una fecha de inicio en H1 y una fecha de fin en I1. Las ventas comprendidas entre ambas, incluidos los dos días:

=SUMAR.SI.CONJUNTO(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Errores frecuentes

  • Comillas y &: la comparación va entre comillas y la celda se añade detrás con &: ">="&H1. Si escribe ">=H1", Euro-Office busca el texto H1 y el resultado es 0.
  • Fechas que incluyen una hora (16-11-2026 14:32) quedan fuera de "<="&FIN.MES(...) el último día del mes, porque este corresponde a la medianoche. En ese caso, utilice como segunda condición "<"&FECHA.MES($A2;1): menor que el primer día del mes siguiente.
  • Filtrar solo por número de mes, por ejemplo con MES() en una columna auxiliar, suma enero de 2025 y enero de 2026. Incluya siempre el año.
  • Las fechas guardadas como texto no se tienen en cuenta. Consulte Fechas que llegan como texto o con el día y el mes invertidos.

Un momento…

Configure sus dominios

Configure para cada dominio los servidores de nombres, la vinculación a su hosting y quién será el titular.

Cargando sus dominios…